home *** CD-ROM | disk | FTP | other *** search
/ SGI Freeware 1998 November / Freeware November 1998.img / dist / fw_emacs.idb / usr / freeware / share / emacs / 19.34 / lisp / compare-w.el.z / compare-w.el
Lisp/Scheme  |  1998-10-27  |  6KB  |  174 lines
  1. ;;; compare-w.el --- compare text between windows for Emacs.
  2.  
  3. ;; Copyright (C) 1986, 1989, 1993 Free Software Foundation, Inc.
  4.  
  5. ;; Maintainer: FSF
  6.  
  7. ;; This file is part of GNU Emacs.
  8.  
  9. ;; GNU Emacs is free software; you can redistribute it and/or modify
  10. ;; it under the terms of the GNU General Public License as published by
  11. ;; the Free Software Foundation; either version 2, or (at your option)
  12. ;; any later version.
  13.  
  14. ;; GNU Emacs is distributed in the hope that it will be useful,
  15. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17. ;; GNU General Public License for more details.
  18.  
  19. ;; You should have received a copy of the GNU General Public License
  20. ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21. ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22. ;; Boston, MA 02111-1307, USA.
  23.  
  24. ;;; Commentary:
  25.  
  26. ;; This package provides one entry point, compare-windows.  It compares
  27. ;; text starting from point in two adjacent windows, advancing point
  28. ;; until it finds a difference.  Option variables permit you to ignore
  29. ;; whitespace differences, or case differences, or both.
  30.  
  31. ;;; Code:
  32.  
  33. (defvar compare-windows-whitespace "[ \t\n]+"
  34.   "*Regexp that defines whitespace sequences for \\[compare-windows].
  35. Changes in whitespace are optionally ignored.
  36.  
  37. The value of `compare-windows-whitespace' may instead be a function; this
  38. function is called in each buffer, with point at the current scanning point.
  39. The function's job is to categorize any whitespace around (including before)
  40. point; it should also advance past any whitespace.
  41.  
  42. The function is passed one argument, the point where `compare-windows'
  43. was originally called; it should not consider any text before that point.
  44. If the function returns the same value for both buffers, then the
  45. whitespace is considered to match, and is skipped.")
  46.  
  47. (defvar compare-ignore-case nil
  48.   "*Non-nil means \\[compare-windows] ignores case differences.")
  49.  
  50. ;;;###autoload
  51. (defun compare-windows (ignore-whitespace)
  52.   "Compare text in current window with text in next window.
  53. Compares the text starting at point in each window,
  54. moving over text in each one as far as they match.
  55.  
  56. This command pushes the mark in each window
  57. at the prior location of point in that window.
  58. If both windows display the same buffer,
  59. the mark is pushed twice in that buffer:
  60. first in the other window, then in the selected window.
  61.  
  62. A prefix arg means ignore changes in whitespace.
  63. The variable `compare-windows-whitespace' controls how whitespace is skipped.
  64. If `compare-ignore-case' is non-nil, changes in case are also ignored."
  65.   (interactive "P")
  66.   (let* (p1 p2 maxp1 maxp2 b1 b2 w2
  67.         success size
  68.         (opoint1 (point))
  69.         opoint2
  70.         (skip-whitespace (if ignore-whitespace
  71.                  compare-windows-whitespace)))
  72.     (setq p1 (point) b1 (current-buffer))
  73.     (setq w2 (next-window (selected-window)))
  74.     (if (eq w2 (selected-window))
  75.     (error "No other window"))
  76.     (setq p2 (window-point w2)
  77.       b2 (window-buffer w2))
  78.     (setq opoint2 p2)
  79.     (setq maxp1 (point-max))
  80.     (save-excursion
  81.       (set-buffer b2)
  82.       (push-mark p2 t)
  83.       (setq maxp2 (point-max)))
  84.     (push-mark)
  85.  
  86.     (setq success t)
  87.     (while success
  88.       (setq success nil)
  89.       ;; if interrupted, show how far we've gotten
  90.       (goto-char p1)
  91.       (set-window-point w2 p2)
  92.  
  93.       ;; If both buffers have whitespace next to point,
  94.       ;; optionally skip over it.
  95.  
  96.       (and skip-whitespace
  97.        (save-excursion
  98.          (let (p1a p2a w1 w2 result1 result2)
  99.            (setq result1
  100.              (if (stringp skip-whitespace)
  101.              (compare-windows-skip-whitespace opoint1)
  102.                (funcall skip-whitespace opoint1)))
  103.            (setq p1a (point))
  104.            (set-buffer b2)
  105.            (goto-char p2)
  106.            (setq result2
  107.              (if (stringp skip-whitespace)
  108.              (compare-windows-skip-whitespace opoint2)
  109.                (funcall skip-whitespace opoint2)))
  110.            (setq p2a (point))
  111.            (if (or (stringp skip-whitespace)
  112.                (and result1 result2 (eq result1 result2)))
  113.            (setq p1 p1a
  114.              p2 p2a)))))
  115.  
  116.       ;; Try advancing comparing 1000 chars at a time.
  117.       ;; When that fails, go 500 chars at a time, and so on.
  118.       (let ((size 1000)
  119.         success-1
  120.         (case-fold-search compare-ignore-case))
  121.     (while (> size 0)
  122.       (setq success-1 t)
  123.       ;; Try comparing SIZE chars at a time, repeatedly, till that fails.
  124.       (while success-1
  125.         (setq size (min size (- maxp1 p1) (- maxp2 p2)))
  126.         (setq success-1
  127.           (and (> size 0)
  128.                (= 0 (compare-buffer-substrings b2 p2 (+ size p2)
  129.                                b1 p1 (+ size p1)))))
  130.         (if success-1
  131.         (setq p1 (+ p1 size) p2 (+ p2 size)
  132.               success t)))
  133.       ;; If SIZE chars don't match, try fewer.
  134.       (setq size (/ size 2)))))
  135.  
  136.     (goto-char p1)
  137.     (set-window-point w2 p2)
  138.     (if (= (point) opoint1)
  139.     (ding))))
  140.  
  141. ;; Move forward over whatever might be called whitespace.
  142. ;; compare-windows-whitespace is a regexp that matches whitespace.
  143. ;; Match it at various starting points before the original point
  144. ;; and find the latest point at which a match ends.
  145. ;; Don't try starting points before START, though.
  146. ;; Value is non-nil if whitespace is found.
  147.  
  148. ;; If there is whitespace before point, but none after,
  149. ;; then return t, but don't advance point.
  150. (defun compare-windows-skip-whitespace (start)
  151.   (let ((end (point))
  152.     (beg (point))
  153.     (opoint (point)))
  154.     (while (or (and (looking-at compare-windows-whitespace)
  155.             (<= end (match-end 0))
  156.             ;; This match goes past END, so advance END.
  157.             (progn (setq end (match-end 0))
  158.                (> (point) start)))
  159.            (and (/= (point) start)
  160.             ;; Consider at least the char before point,
  161.             ;; unless it is also before START.
  162.             (= (point) opoint)))
  163.       ;; keep going back until whitespace
  164.       ;; doesn't extend to or past end
  165.       (forward-char -1))
  166.     (setq beg (point))
  167.     (goto-char end)
  168.     (or (/= beg opoint)
  169.     (/= end opoint))))
  170.  
  171. (provide 'compare-w)
  172.  
  173. ;;; compare-w.el ends here
  174.